Settings Backup

[Gray Wolf]

Here's a batch file to backup Studio One settings, any version. It copies settings to \Documents\Studio One Settings Backups, although you can edit that to point it anywhere else if you want. Run it, enter the version number when prompted, hit Enter and go back to doing whatever you were doing while it makes the backup.

Might be handy for those without access to Studio One+ backup. Copy and paste the text into Notepad or any text editor and save it as a *.bat file.

@echo off
rem Prompt for the version number
set /p version=Enter the PreSonus Studio One version number:
rem Get the current date and time using wmic (format: YYYYMMDDhhmmss)
for /f "tokens=2 delims==" %%I in ('wmic os get localdatetime /value') do set datetime=%%I
rem Extract the components of the datetime
set year=%datetime:~0,4%
set month=%datetime:~4,2%
set day=%datetime:~6,2%
set hour=%datetime:~8,2%
set min=%datetime:~10,2%
set sec=%datetime:~12,2%
rem Set the base source path and dynamically build the source path using the version number
set source="C:\Users\%username%\AppData\Roaming\PreSonus\Studio One %version%"
rem Define the base destination folder path
set destination="C:\Users\%username%\Documents\Studio One Settings Backups\Studio One %version% - %month%_%day%_%year%_%hour%_%min%_%sec%"
rem Create the destination folder if it does not exist
if not exist %destination% mkdir %destination%
rem Use robocopy to copy files and directories, including all subdirectories
robocopy %source% %destination% /E /Z /XA:H /R:3 /W:5 /V
echo Backup completed!
pause

 

[Davey]

Nice one. An improvement might be to exclude the Extensions subfolder. All that stuff is downloaded & installed by S1 and excluding it makes the backup dramatically smaller. Mine shrinks from 1.84 GB to 0.03 GB, the vast bulk of that being the stem separation extension @ 1.6 GB.

 

[Gray Wolf]

You can modify it to do that.
edited for an error, I had used %sourcefolder% instead of %destination% which fails

rem Define the folder to exclude
set excludedFolder="C:\Users\%username%\AppData\Roaming\PreSonus\Studio One %version%\Extensions"

rem Use robocopy to copy files and directories
robocopy %source% %destination% /E /Z /XA:H /R:3 /W:5 /V /XD %excludedFolder%

 

[Gray Wolf]

Actually this is better, to only exclude stem separation, the elephant in the room.

rem Define a folder to exclude
set excludedFolder="C:\Users\%username%\AppData\Roaming\PreSonus\Studio One %version%\Extensions\presonus.studioone.stemseparation.win"

rem Use robocopy to copy files and directories
robocopy %source% %destination% /E /Z /XA:H /R:3 /W:5 /V /XD %excludedFolder%

 

[Davey]

Actually this is better, to only exclude stem separation, the elephant in the room.

rem Define a folder to exclude
set excludedFolder="C:\Users\%username%\AppData\Roaming\PreSonus\Studio One %version%\Extensions\presonus.studioone.stemseparation.win"

rem Use robocopy to copy files and directories
robocopy %source% %destination% /E /Z /XA:H /R:3 /W:5 /V /XD %excludedFolder%

Yes, better still, not least because I guess there could be some non-Presonus extensions like the stuff Lukas makes. Slightly interestingly the stem separation installs in two flavours, one for x64 and one for arm64, so half of that space is always a waste on any particular machine. Not a big deal though.

 

[Gray Wolf]

Yes, better still, not least because I guess there could be some non-Presonus extensions like the stuff Lukas makes. Slightly interestingly the stem separation installs in two flavours, one for x64 and one for arm64, so half of that space is always a waste on any particular machine. Not a big deal though.

True. I would suppose the same may be true on mac for Intel/Silicon, but yeah, that's 840mb of wasted space on Windows. I deleted the arm64 part of it on my machine.